;+
; NAME:
;  oclc_ey92_aseries
; PURPOSE: (one line)
;  return power series in 1/lam used by EY92
; DESCRIPTION:
;  return power series in 1/lam used by EY92
; CATEGORY:
;  Occultation lightcurve (oclc)
; CALLING SEQUENCE:
;  aser = oclc_ey92_aseries(a,b,order,delta)
; INPUTS:
;  a - exponent for non-constant mean moleculr weight
;      mu(r) = mu0 * (r/r0)^-a
;  b - exponent for non-constant temperature
;      T(r) = T * (r/r0)^b
;  order - order of delta in the series (default 4)
;  delta - 1/lambda (may be an array)
; OPTIONAL INPUT PARAMETERS:
; KEYWORD INPUT PARAMETERS:
;  none
; KEYWORD OUTPUT PARAMETERS:
;  none
; OUTPUTS:
;  A(delta,a,b) 
;  Series in delta for use in calculating theta
;  Unitless.
; COMMON BLOCKS:
;  None
; SIDE EFFECTS:
; RESTRICTIONS:
;  None
; PROCEDURE:
;  Elliot and Young 1992, AJ 103, pp 991; eg A2
; MODIFICATION HISTORY:
;  Written 2006 Jun 28, Leslie Young
;-


function oclc_ey92_aseries, a,b, order, delta

    aser = 1.d

    if order eq 0 then return, aser

    aser = aser + (-(3.d + a)/8.d + 3*b/8.d) * delta

    if order eq 1 then return, aser

    aser = aser + (-(15. + 26 * a + 7 * a^2.)/128.d + $
                   (7. + 5*a)*b/64.d + $
                   (b^2.)/128.d ) * (delta ^(2.d))

    if order eq 2 then return, aser

    aser = aser + (-(105. + 425 * a + 355.*a^2 + 75*a^3)/1024.d + $
                   (27. + 50. * a + 35. * a^2.) * b/1024. + $
                   (69. + 55. * a) * b^2./1024. + $
                   (9.) * b^3 / 1024.) * delta^3.

    if order eq 3 then return, aser

    aser = aser + ( (-4725. + 35196.*a + 57134.*a^2 + 31836.*a^3 + 5509.*a^4) * (1/32768.) $
                    - (1059. + 4907 * a + 3857. * a^2 + 609 * a^3) * (b/8192.) $
                    + (2353. + 4326.* a + 2233.* a^2)  * (b^2/16384.) $
                    + (941. + 791. * a) * (b^3/8192.) + 491 * (b^4/32768.) ) * delta^4
    return, aser

end