;+
; NAME:
;  oclc_ey92_bseries
; PURPOSE: (one line)
;  return power series in 1/lam used by EY92
; DESCRIPTION:
;  return power series in 1/lam used by EY92
; CATEGORY:
;  Occultation lightcurve (oclc)
; CALLING SEQUENCE:
;  bser = oclc_ey92_bseries(a,b,order,delta)
; INPUTS:
;  a - exponent for non-constant mean moleculr weight
;      mu(r) = mu0 * (r/r0)^-a
;  b - exponent for non-constant temperature
;      T(r) = T * (r/r0)^b
;  order - order of delta in the series (default 4)
;  delta - 1/lambda (may be an array)
; OPTIONAL INPUT PARAMETERS:
; KEYWORD INPUT PARAMETERS:
;  none
; KEYWORD OUTPUT PARAMETERS:
;  none
; OUTPUTS:
;  B(a,b,delta)
;  Series in delta for use in calculating dtheta
;  Unitless.
; COMMON BLOCKS:
;  None
; SIDE EFFECTS:
; RESTRICTIONS:
;  None
; PROCEDURE:
;  Elliot and Young 1992, AJ 103, pp 991; eg A2
; MODIFICATION HISTORY:
;  Written 2006 Jun 28, Leslie Young
;-


function oclc_ey92_bseries, a,b,order,delta

    bser = 1.d

    if order eq 0 then return, bser

    bser = bser + ((1.d + 3. * a)/8.d + 15. * b/8.d) * delta

    if order eq 1 then return, bser

    bser = bser + ((9. + 6 * a +  a^2.)/128.d + $
                   (-1.)*(17. + 11*a)*b/64.d + $
                   (25. * b^2.)/128.d ) * (delta ^(2.d))

    if order eq 2 then return, bser

    bser = bser + ((75. + 67 * a + 41.*a^2 + 9*a^3)/1024.d + $
                   (-1.)*(81. + 134. * a + 57. * a^2.) * b/1024. + $
                   (1. + 3. * a) * b^2./1024. + $
                   (5.) * b^3 / 1024.) * delta^3.

    if order eq 3 then return, bser

    bser = bser + ( (3675. + 7204.*a + 5266.*a^2 + 2564.*a^3 + 491.*a^4) * (1/32768.) $
                    - (339. + 1347 * a + 1297. * a^2 + 409 * a^3) * (b/8192.) $
                    - (10555. + 1834.* a + 807.* a^2)  * (b^2/16384.) $
                    - (67. + 49. * a) * (b^3/8192.) + 59 * (b^4/32768.) ) * delta^4

    return, bser

end