function mk_nuwgt, lnarr, nuwgtarr

;+
; NAME:
;  mk_nuwgt
; PURPOSE: (one line)
;  make a list of inverse cm (and optionally, weights)
; DESCRIPTION:
;  pick nu's appropriate for the temperature
; CATEGORY:
;  Spectra
; CALLING SEQUENCE:
;  nuarr = mk_nuwgt(lnarr, nuwgt)
; INPUTS:
;  lnarr - an array of spectral line structures to be changed
; OPTIONAL INPUT PARAMETERS:
;  none
; KEYWORD INPUT PARAMETERS:
;  none
; KEYWORD OUTPUT PARAMETERS:
;  none
; OUTPUTS:
;  nu - array of wavenumbers (inverse cm)
;  nuwgt - array of wavenumber weights (inverse cm)
; COMMON BLOCKS:
;  None
; SIDE EFFECTS:
; RESTRICTIONS:
;  None
; PROCEDURE:
; MODIFICATION HISTORY:
;  Written 2001 May, by Leslie Young, SwRI
;-

; shortward of the first line
  ad = lnarr[0].dopw
  nu0 = lnarr[0].nu0
  gauleg, nu0 - 500.d*ad, nu0-3.d*ad, nu, w, 50
  nuarr=nu
  nuwgtarr = w

  n=(size(lnarr))(1)

  for i=0L, n-2 do begin
    nu0 = lnarr[i].nu0
    ad0 = lnarr[i].dopw
    nu1 = lnarr[i+1].nu0
    ad1 = lnarr[i+1].dopw
    gauleg, nu0-3.d*ad0, nu0+3.d*ad0, nu, w, 9
    nuarr=[nuarr,nu]
    nuwgtarr = [nuwgtarr,w]
    if nu0+500*ad0 ge nu1-500*ad1 then begin
      gauleg, nu0  +3.d*ad0, nu1-3.d*ad1, nu, w, 100 
      nuarr=[nuarr,nu]
      nuwgtarr = [nuwgtarr,w]
    end else begin
      gauleg, nu0  +3.d*ad0, nu0+500.d*ad1, nu, w, 50 
      nuarr=[nuarr,nu]
      nuwgtarr = [nuwgtarr,w]
      gauleg, nu1-500.d*ad0, nu1-3.d*ad1, nu, w, 50 
      nuarr=[nuarr,nu]
      nuwgtarr = [nuwgtarr,w]
    end
  end

  return, nuarr

end