;  Given a number of points and a spacing, return an
;  array of the wavelet fourier series and the
;  array of frequencies (2 pi/wavelength) for the
;  j, k=0 wavelet for use with the refractivity.

function refr_j0_wL, n, d, j,wL

  dn = d * n
  wL=[findgen(n/2)-n/2,findgen(n/2)] * 2. * !pi/dn
  wabsL = 2.^(-j) * abs(wL)
  wtimesL = wabsL * 3./!pi
  
  ; initialize the return array with zeros.
  psihatL = complexarr(n)
  
  ; fill in case # 1
  gd = where (wtimesL gt 2. and wtimesL lt 4., ngd)
  if ngd gt 0 then begin
     psihatL[gd] = 1.-refr_mother_wL_g(wabsL[gd])
  end

  ; fill in case # 2
  gd = where (wtimesL eq 4., ngd)
  if ngd gt 0 then begin
     psihatL[gd] = 1.
  end

  ; fill in case # 3
  gd = where (wtimesL gt 4. and wtimesL lt 8., ngd)
  if ngd gt 0 then begin
     psihatL[gd] = refr_mother_wL_g(wabsL[gd]/2.)
  end
  
  ; multiply by exp(-iw/2)
  gd = where (wtimesL gt 2. and wtimesL lt 8., ngd)
  if ngd gt 0 then begin
     psihatL[gd] = 2.^(-j/2.) * sqrt(psihatL[gd]) * exp(-complex(0,1)*wL[gd]/2.)
  end
  
  return, psihatL

end